set term pngcairo size 1000, 800
set grid

f1(x) = a1*x+b1
fit f1(x) 's(T).plot' using 1:2:3 yerr via a1, b1
f2(x) = a2*x+b2
fit f2(x) 'q(T).plot' using 1:2:3 yerr via a2, b2
f3(x) = a3*x+b3
fit f3(x) 'U(T).plot' using 1:2:3 yerr via a3, b3


set output 's(T).png'
set title "Зависимость коэффицента поверхностного натяжения от температуры"
set xlabel "T, К"
set ylabel "sigma, Н/м"

plot 	's(T).plot' using 1:2:3 with yerrorbars notitle lc 0 pt 1 lw 2,	\
	f1(x) title "" lc rgb "red"


set output 'q(T),U(T).png'
set title "Зависимости теплоты изотермического образования и поверхностной плотности внутренней энергии от температуры"
set ytics nomirror
set y2tics
set xlabel "Т, К"
set ylabel "q, дж/м^2"
set y2label "U, дж/м^2"
set yrange[1.1:1.8]
set y2range[1:10]
plot	'q(T).plot'	using 1:2:3 with yerrorbars axes x1y1 notitle lc 0 pt 1 lw 2,		\
	'U(T).plot'	using 1:2:3 with yerrorbars axes x1y2 notitle lc 0 pt 1 lw 2,		\
	f2(x)		lc rgb "red" axes x1y1 notitle,				\
	f3(x)		lc rgb "red" axes x1y2 notitle,				\
        'q(T).plot'	with lines lc rgb "green" axes x1y1 title "q(T)",	\
        'U(T).plot'	with lines lc rgb "blue" axes x1y2 title "U(T)"
unset y2tics
unset y2label
unset xrange
unset yrange

set xlabel "x, мм"
set ylabel "f, мН"

set output 'f1(x).png'
set title "Зависимость силы натяжения от координаты (T = 293К)"
plot	'f(x)1.plot'	notitle lc 0 pt 1 lw 2	,\
	'f(x)1.plot'	notitle with lines lc rgb "blue" 

set output 'f2(x).png'
set title "Зависимость силы натяжения от координаты (T = 293К)"
plot	'f(x)2.plot'	notitle lc 0 pt 1 lw 2	,\
	'f(x)2.plot'	notitle with lines lc rgb "blue"

set output 'f3(x).png'
set title "Зависимость силы натяжения от координаты (T = 343-333К)"
plot	'f(x)3.plot'	notitle lc 0 pt 1 lw 2	,\
	'f(x)3.plot'	notitle with lines lc rgb "red"

set output 'f4(x).png'
set title "Зависимость силы натяжения от координаты (T = 336-330К)"
plot	'f(x)4.plot'	notitle lc 0 pt 1 lw 2	,\
	'f(x)4.plot'	notitle with lines lc rgb "green"